Gibson, K. E., Little, J., Cowlishaw, S., Toromon, T., O’Donnell, M. L.  (2021). 
Piloting a scalable, post-trauma psychosocial intervention in Tuvalu: 
The Skills fOr Life Adjustment and Resilience (SOLAR) Program.  
European Journal of Psychotraumatology, 12:1, 1948253. doi: 10.1080/20008198.2021.1948253

Supplementary Mplus Input File for between-subjects ANCOVA of PSYCHLOPS scores

TITLE:  Model 4a;
DATA:
FILE IS 'C:\Solar Data - Mplus.dat';
LISTWISE = OFF; !Invokes FILM to handle missingness when used with MLR estimation;
VARIABLE:
NAMES = Tx_Group
T1_PYCH  !Time 1 PYCH score;
T2_PYCH; !Time 2 PYCH score;
USEVARIABLES = 
T1_PYCH T2_PYCH;
MISSING ARE ALL (9999); 
GROUPING = Tx_Group (1=UC 2=Treatment); !Define group membership;
DEFINE: 
CENTER T1_PYCH(GRANDMEAN); !Grandcentre Time 1 PYCH score;
ANALYSIS:  Type=MGROUP;
           Estimator = MLR; 
MODEL:     T2_PYCH ON T1_PYCH (s1); !slopes for the covariate are constrained to be equal across groups.
                    T2_PYCH; !Variances for T2_PYCH free to differ across groups.
Model UC:              [T2_PYCH]; !Mean score for Group UC;
Model Treatment:  [T2_PYCH]; !Mean score for Group Treatment;
OUTPUT:  SAMPSTAT STDYX CINTERVAL;

TITLE:  Model 4b;
DATA:
FILE IS 'C:\Solar Data - Mplus.dat';
LISTWISE = OFF;  
VARIABLE:
NAMES = Tx_Group
T1_PYCH  !Time 1 PYCH score;
T2_PYCH; !Time 2 PYCH score;
USEVARIABLES = 
T1_PYCH T2_PYCH;
MISSING ARE ALL (9999); 
GROUPING = Tx_Group (1=UC 2=Treatment); !Define group membership;
DEFINE: 
CENTER T1_PYCH(GRANDMEAN); !Grandcentre Time 1 PYCH score;

ANALYSIS:  Type=MGROUP;
           Estimator = MLR; 
MODEL:     T2_PYCH ON T1_PYCH (s1); !slopes for the covariate are constrained to be equal across groups.
                    T2_PYCH (e1); !Variances for T2_PYCH constrained to be equal across groups.
Model UC:              [T2_PYCH]; !Mean score for Group UC;
Model Treatment:  [T2_PYCH]; !Mean score for Group Treatment;
OUTPUT:  SAMPSTAT STDYX CINTERVAL;

TITLE:  Model 4c;
DATA:
FILE IS 'C:\Solar Data - Mplus.dat';
LISTWISE = OFF; 
VARIABLE:
NAMES = Tx_Group
T1_PYCH  !Time 1 PYCH score;
T2_PYCH; !Time 2 PYCH score;
USEVARIABLES = 
T1_PYCH T2_PYCH;
MISSING ARE ALL (9999); 
GROUPING = Tx_Group (1=UC 2=Treatment); !Define group membership;
DEFINE: 
CENTER T1_PYCH(GRANDMEAN); !Grandcentre Time 1 PYCH score;
ANALYSIS:  Type=MGROUP;
                       Estimator = MLR; 
MODEL:     T2_PYCH ON T1_PYCH (s1); !slopes for the covariate are constrained to be equal across groups.
                    T2_PYCH (e1); !Variances for T2_PYCH constrained to be equal across groups.
Model UC:              [T2_PYCH] (A1); !Mean score constrained to be equal across groups;
Model Treatment:  [T2_PYCH] (A1); !Mean score constrained to be equal across groups;
OUTPUT:  SAMPSTAT STDYX CINTERVAL;